home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 19 / CU Amiga Magazine's Super CD-ROM 19 (1998)(EMAP Images)(GB)[!][issue 1998-02].iso / CUCD / Magazine / SoundLab / Studio16add / sources / KStudioCheck.asm < prev    next >
Encoding:
Assembly Source File  |  1997-12-10  |  3.0 KB  |  126 lines
  1. *>b:KStudioCheck
  2.  
  3.     *«««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««*
  4.     *   Copyright © 1997 by Kenneth "Kenny" Nilsen.  E-Mail: kenny@bgnett.no              *
  5.     *   Source viewed in 800x600 with mallx.font (11) in CED                      *
  6.     *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  7.     *
  8.     *   Name
  9.     *    KStudioCheck 2
  10.     *
  11.     *   Function
  12.     *    Count number of AD516/AD1012 cards installed
  13.     *
  14.     *   Created    : 03.12.97
  15.     *   Changes    : 
  16.     *««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««««*
  17.  
  18.  
  19.         Incdir    inc:
  20.  
  21.         include    lvo/exec_lib.i
  22.         include    lvo/dos_lib.i
  23.         include    lvo/expansion_lib.i
  24.  
  25.         include    digital.macs
  26.         include    libraries/configvars.i
  27.  
  28.         Incdir    ""
  29.  
  30. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  31. LibBase    macro
  32.     move.l    \1basX(pc),a6
  33.     endm
  34. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  35. Start    move.l    $4.w,a6
  36.  
  37. ; -- open libs
  38.  
  39.     lea    DosName(pc),a1
  40.     moveq    #37,d0
  41.     Call    OpenLibrary        ;open dos.library
  42.     move.l    d0,DosbasX
  43.     beq    .exit
  44.  
  45.     lea    ExpName(pc),a1
  46.     moveq    #37,d0
  47.     Call    OpenLibrary        ;open expansion.library
  48.     move.l    d0,ExpansionbasX
  49.     beq    .exit
  50.  
  51. ; -- check hardware
  52.  
  53.     LibBase    expansion
  54.     lea    Number516(pc),a5
  55.     moveq    #2,d7
  56.     bsr    CheckAD            ;check AD516
  57.     lea    2(a5),a5
  58.     subq.l    #1,d7
  59.     bsr    CheckAD            ;check AD1012
  60.  
  61. ; -- show info to user
  62.  
  63.     LibBase    dos
  64.     Call    Output
  65.     move.l    d0,d1
  66.     beq    .exit            ;no default IO was available
  67.     move.l    #String,d2
  68.     move.l    #Number516,d3
  69.     Call    VFPrintF        ;format and write to StdIO
  70.  
  71. ; -- exit and cleanup
  72.  
  73. .exit    move.l    $4.w,a6
  74.  
  75.     move.l    DosbasX(pc),d0
  76.     beq    .noDos
  77.     move.l    d0,a1
  78.     Call    CloseLibrary
  79.  
  80. .noDos    move.l    ExpansionbasX(pc),d0
  81.     beq    .noExp
  82.     move.l    d0,a1
  83.     Call    CloseLibrary
  84.  
  85. .noExp    tst.w    Numberuse
  86.     beq    .noUse
  87.     move.b    #5,Warn+3
  88. .noUse    move.l    Warn(pc),d0
  89.     rts
  90. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  91. CheckAD    moveq    #0,d6        ;lastBoard
  92. .loop    move.l    d7,d1
  93.     move.l    d6,a0
  94.     move.l    #2127,d0    ;Sunrize
  95.     Call    FindConfigDev    ;find a card
  96.     move.l    d0,d6
  97.     beq    .exit        ;no card, exit
  98.  
  99.     clr.b    Warn+3        ;we have a card
  100.     add.w    #1,(a5)        ;counter for this card
  101.  
  102.     move.l    d0,a0
  103.     tst.l    cd_driver(a0)    ;check if in use
  104.     beq    .loop
  105.     add.b    #1,NumberUse+1    ;counter for active card(s)
  106.     bra    .loop
  107.  
  108. .exit    rts
  109. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  110. Warn        dc.l    5
  111.  
  112. Number516    dc.w    0
  113. Number1012    dc.w    0
  114. NumberUse    dc.w    0
  115.  
  116. DosbasX        dc.l    0
  117. ExpansionbasX    dc.l    0
  118. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  119. String        dc.b    27,"[1m%d AD516",27,"[0m and ",27,"[1m%d AD1012",27,"[0m installed. %d in use.",10,0
  120.  
  121.         dc.b    "$VER: KStudioCheck 2.0 (03.12.97) by Kenneth 'Kenny' Nilsen",10,0
  122.  
  123. DosName        dc.b    "dos.library",0
  124. ExpName        dc.b    "expansion.library",0
  125. *»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»»*
  126.